Remove some state moved declarations

Customised the forward auth in authelia to ignore Authorization headers as authelia was failing to parse the Authorization: MediaBrowser headers that jellyfin uses.

1-nixos-node/configuration.nix

@@ -113,6 +113,50 @@
   networking.firewall.allowedTCPPorts = [ 80 443 8081 4646 4647 4648 8300 8301 8500 ];
   networking.firewall.allowedUDPPorts = [ 8301 ];
 
+  # Ensure Docker daemon is available (Nomad enableDocker only configures Nomad, does not guarantee docker service)
+  virtualisation.docker.enable = true;
+
+  # Proper systemd service definition for macvlan network creation
+  systemd.services.docker-macvlan-network = {
+    description = "Ensure macvlan Docker network exists";
+    after = [ "network-online.target" "docker.service" ];
+    wants = [ "network-online.target" "docker.service" ];
+    wantedBy = [ "multi-user.target" ];
+    serviceConfig = {
+      Type = "oneshot";
+    };
+    # Provide required binaries in PATH
+    path = [ pkgs.docker pkgs.bash pkgs.coreutils pkgs.iproute2 pkgs.gnugrep ];
+    script = ''
+      set -euo pipefail
+      NET_NAME=macvlan
+      if docker network inspect "$NET_NAME" >/dev/null 2>&1; then
+        echo "Docker network $NET_NAME already exists"
+        exit 0
+      fi
+      echo "Creating Docker macvlan network $NET_NAME on interface ${bind_interface}"
+      # We intentionally do NOT use --ip-range here to avoid allocating the
+      # same reserved pool on every host (which could lead to collisions if
+      # multiple macvlan containers are started across nodes). Instead, we
+      # give critical services (like UniFi) an explicit static IP via the
+      # Nomad job (Docker static assignment) and rely on manual DHCP
+      # reservations to prevent conflicts.
+      #
+      # If you later need multiple macvlan-assigned containers per host,
+      # consider one of these strategies:
+      #  1. Per-host distinct network name + ip-range slice (macvlan-m01, ...)
+      #  2. Parameterize an ip-range per host in Terraform and template here
+      #  3. Keep a registry of allocated static IPs in Consul KV / Nomad vars
+      docker network create -d macvlan \
+        --subnet=192.168.1.0/24 \
+        --gateway=192.168.1.1 \
+        -o parent=${bind_interface} \
+        "$NET_NAME"
+      echo "Docker macvlan network $NET_NAME created"
+    '';
+    restartIfChanged = false; # Don't rerun just because comment changed
+  };
+
   # Copy the NixOS configuration file and link it from the resulting system
   # (/run/current-system/configuration.nix). This is useful in case you
   # accidentally delete configuration.nix.

2-nomad-config/1-data/postgres.tf

@@ -18,27 +18,9 @@ resource "nomad_variable" "postgres" {
   }
 }
 
-resource "nomad_csi_volume_registration" "unraid_database_dump" {
-  #Note: Before chaning the definition of this volume you need to stop the jobs that are using it
-  depends_on = [data.nomad_plugin.smb]
-  plugin_id  = "smb"
-
-  volume_id = "unraid_database_dump"
-  name      = "unraid_database_dump"
-
-  external_id = "unraid_database_dump"
-
-  capability {
-    access_mode     = "single-node-writer"
-    attachment_mode = "file-system"
-  }
-
-  context = {
-    source = "//192.168.1.192/database-dump"
-  }
-
-  secrets = {
-    "username" = "nomad"
-    "password" = data.sops_file.secrets.data["unraid.nomad"]
-  }
+module "unraid_smb_database_dump" {
+  source = "../modules/unraid_smb"
+  name   = "dump"
+  id     = "unraid_database_dump"
+  share  = "database-dump"
 }

2-nomad-config/2-ingress.tf

@@ -2,30 +2,3 @@
 module "ingress" {
   source = "./2-ingress"
 }
-
-# traefik.tf
-
-moved {
-  from = cloudflare_dns_record.othrayte-one
-  to   = module.ingress.cloudflare_dns_record.othrayte-one
-}
-
-moved {
-  from = cloudflare_dns_record.star-othrayte-one
-  to   = module.ingress.cloudflare_dns_record.star-othrayte-one
-}
-
-moved {
-  from = nomad_variable.traefik
-  to   = module.ingress.nomad_variable.traefik
-}
-
-moved {
-  from = nomad_job.traefik
-  to   = module.ingress.nomad_job.traefik
-}
-
-moved {
-  from = nomad_csi_volume_registration.unraid_appdata_traefik
-  to   = module.ingress.nomad_csi_volume_registration.unraid_appdata_traefik
-}

2-nomad-config/2-ingress/authelia.nomad.hcl

@@ -63,6 +63,12 @@ job "authelia" {
         data = <<EOF
 server:
   address: tcp://0.0.0.0:{{ env "NOMAD_PORT_http" }}/
+  endpoints:
+    authz:
+      forward-auth:
+        implementation: 'ForwardAuth'
+        authn_strategies:
+          - name: 'CookieSession'
 theme: "auto"
 identity_validation:
   reset_password:

2-nomad-config/2-ingress/traefik.nomad.hcl

@@ -112,6 +112,9 @@ EOF
       template {
         data = <<EOF
 http:
+  serversTransports:
+    ignorecert:
+      insecureSkipVerify: true
   middlewares:
     auth:
       forwardAuth:
@@ -173,6 +176,11 @@ http:
     hass-token:
       rule: "Host(`${hass_magic_token}-hass.othrayte.one`)"
       service: hass
+    unifi-network:
+      rule: "Host(`network.othrayte.one`)"
+      service: unifi-network
+      middlewares:
+        - auth
 
   services:
     traefik:
@@ -190,19 +198,24 @@ http:
     unraid:
       loadBalancer:
         servers:
-          - url: "http://192.168.1.192:80"
+          - url: "http://betelgeuse-seven-unraid.lan:80"
     frigate:
       loadBalancer:
         servers:
-          - url: "http://192.168.1.192:5000"
+          - url: "http://betelgeuse-seven-unraid.lan:5000"
     kopia:
       loadBalancer:
         servers:
-          - url: "http://192.168.1.192:51515"
+          - url: "http://betelgeuse-seven-unraid.lan:51515"
     hass:
       loadBalancer:
         servers:
           - url: "http://192.168.1.234:8123"
+    unifi-network:
+      loadBalancer:
+        serversTransport: ignorecert
+        servers:
+          - url: "https://192.168.1.50:8443"
 EOF
 
         destination = "local/configs/nomad.yml"

2-nomad-config/2-ingress/traefik.tf

@@ -32,28 +32,8 @@ resource "nomad_job" "traefik" {
   })
 }
 
-resource "nomad_csi_volume_registration" "unraid_appdata_traefik" {
-  #Note: Before chaning the definition of this volume you need to stop the jobs that are using it
-  depends_on = [data.nomad_plugin.smb]
-  plugin_id  = "smb"
-
-  volume_id = "unraid_appdata_traefik"
-  name      = "unraid_appdata_traefik"
-
-  external_id = "unraid_appdata_traefik"
-
-  capability {
+module "appdata_traefik" {
+  source      = "../modules/appdata"
+  name        = "traefik"
   access_mode = "multi-node-multi-writer"
-    attachment_mode = "file-system"
-  }
-
-  context = {
-    source = "//192.168.1.192/appdata"
-    subDir = "traefik" # Note: Needs to be manually created on the share
-  }
-
-  secrets = {
-    "username" = "nomad"
-    "password" = data.sops_file.secrets.data["unraid.nomad"]
-  }
 }

2-nomad-config/deluge.nomad.hcl

@@ -0,0 +1,145 @@
+job "deluge" {
+  group "deluge" {
+    network {
+      mode = "bridge"
+      port "http" {
+        to = 8112
+      }
+    }
+
+    task "wireguard" {
+      driver = "docker"
+
+      lifecycle {
+        hook    = "prestart"
+        sidecar = true
+      }
+
+      config {
+        image      = "thrnz/docker-wireguard-pia:latest"
+        privileged = true
+        ports      = ["http"]
+      }
+
+      env {
+        LOC           = "aus_melbourne"
+        LOCAL_NETWORK = "192.168.1.0/24"
+        # PORT_FORWARDING = "1" # TODO: Find a way to tell deluge the forwarded port, the wireguard container outputs it /pia-shared/port.dat
+      }
+
+      template {
+        data        = <<EOH
+USER="{{ with nomadVar "nomad/jobs/deluge" }}{{ .pia_user }}{{ end }}"
+PASS="{{ with nomadVar "nomad/jobs/deluge" }}{{ .pia_pass }}{{ end }}"
+EOH
+        destination = "secrets/pia.env"
+        env         = true # Load the file as environment variables
+      }
+
+      resources {
+        cpu    = 50
+        memory = 32
+      }
+    }
+
+
+    # Service for Traefik (external ingress)
+    service {
+      name = "deluge"
+      port = "http"
+
+      tags = [
+        "traefik.enable=true",
+        "traefik.http.routers.deluge.middlewares=auth@file",
+      ]
+
+      check {
+        type     = "http"
+        path     = "/"
+        interval = "10s"
+        timeout  = "2s"
+      }
+    }
+
+    # Service for Consul Connect (internal mesh communication)
+    service {
+      name         = "deluge-api"
+      port         = "http"
+      address_mode = "alloc" # Use allocation IP for Connect as the sidecar can't access the host's published port (hairpin/loopback NAT issue)
+
+      # tags = [
+      #   "traefik.enable=false",
+      # ]
+
+      connect {
+        sidecar_service {
+          //tags = ["traefik.enable=false"]
+        }
+      }
+
+      check {
+        type     = "http"
+        path     = "/"
+        interval = "10s"
+        timeout  = "2s"
+      }
+    }
+
+    task "deluge" {
+      driver = "docker"
+
+      config {
+        image        = "lscr.io/linuxserver/deluge:latest"
+        network_mode = "container:wireguard-${NOMAD_ALLOC_ID}" # Share namespace with VPN
+      }
+
+      env {
+        PUID = "1000"
+        PGID = "1000"
+        TZ   = "Australia/Melbourne"
+      }
+
+      volume_mount {
+        volume      = "unraid_appdata_deluge"
+        destination = "/config"
+        read_only   = false
+      }
+
+      volume_mount {
+        volume      = "unraid_media_deluge"
+        destination = "/data/downloads"
+        read_only   = false
+      }
+
+      resources {
+        cpu        = 400
+        memory     = 2048
+        memory_max = 3000
+      }
+    }
+
+    volume "unraid_appdata_deluge" {
+      type            = "csi"
+      read_only       = false
+      source          = "unraid_appdata_deluge"
+      access_mode     = "single-node-writer"
+      attachment_mode = "file-system"
+
+      mount_options {
+        mount_flags = ["uid=1000", "gid=1000"]
+      }
+    }
+
+    volume "unraid_media_deluge" {
+      type            = "csi"
+      read_only       = false
+      source          = "unraid_media_deluge"
+      access_mode     = "single-node-writer"
+      attachment_mode = "file-system"
+
+      mount_options {
+        mount_flags = ["uid=1000", "gid=1000"]
+      }
+    }
+  }
+}

2-nomad-config/deluge.tf

@@ -0,0 +1,24 @@
+
+resource "nomad_job" "deluge" {
+  jobspec = file("deluge.nomad.hcl")
+}
+
+resource "nomad_variable" "deluge" {
+  path = "nomad/jobs/deluge"
+  items = {
+    pia_user = data.sops_file.secrets.data["pia.user"]
+    pia_pass = data.sops_file.secrets.data["pia.pass"]
+  }
+}
+
+module "appdata_deluge" {
+  source = "./modules/appdata"
+  name   = "deluge"
+}
+
+module "unraid_smb_deluge_media" {
+  source = "./modules/unraid_smb"
+  name   = "deluge"
+  share  = "media"
+  subDir = "downloads"
+}

2-nomad-config/gitea.tf

@@ -33,28 +33,7 @@ resource "postgresql_database" "gitea" {
   owner = postgresql_role.gitea.name
 }
 
-resource "nomad_csi_volume_registration" "unraid_appdata_gitea" {
-  #Note: Before chaning the definition of this volume you need to stop the jobs that are using it
-  depends_on = [data.nomad_plugin.smb]
-  plugin_id  = "smb"
-
-  volume_id = "unraid_appdata_gitea"
-  name      = "unraid_appdata_gitea"
-
-  external_id = "unraid_appdata_gitea"
-
-  capability {
-    access_mode     = "single-node-writer"
-    attachment_mode = "file-system"
-  }
-
-  context = {
-    source = "//192.168.1.192/appdata"
-    subDir = "gitea" # Note: Needs to be manually created on the share
-  }
-
-  secrets = {
-    "username" = "nomad"
-    "password" = data.sops_file.secrets.data["unraid.nomad"]
-  }
+module "appdata_gitea" {
+  source = "./modules/appdata"
+  name   = "gitea"
 }

2-nomad-config/immich.tf

@@ -34,107 +34,29 @@ resource "nomad_variable" "immich" {
   }
 }
 
-resource "nomad_csi_volume_registration" "unraid_appdata_immich" {
-  #Note: Before chaning the definition of this volume you need to stop the jobs that are using it
-  depends_on = [data.nomad_plugin.smb]
-  plugin_id  = "smb"
-
-  volume_id = "unraid_appdata_immich"
-  name      = "unraid_appdata_immich"
-
-  external_id = "unraid_appdata_immich"
-
-  capability {
-    access_mode     = "single-node-writer"
-    attachment_mode = "file-system"
+module "appdata_immich" {
+  source = "./modules/appdata"
+  name   = "immich"
 }
 
-  context = {
-    source = "//192.168.1.192/appdata"
-    subDir = "immich" # Note: Needs to be manually created on the share
+module "unraid_smb_immich_photosvideos" {
+  source = "./modules/unraid_smb"
+  name   = "photosvideos"
+  share  = "media"
+  subDir = "Photos and Videos"
 }
 
-  secrets = {
-    "username" = "nomad"
-    "password" = data.sops_file.secrets.data["unraid.nomad"]
-  }
+module "unraid_smb_immich_encodedvideo" {
+  source = "./modules/unraid_smb"
+  name   = "immich_encodedvideo"
+  share  = "media"
+  subDir = "immich/encoded-video"
 }
 
-resource "nomad_csi_volume_registration" "unraid_media_photosvideos" {
-  #Note: Before chaning the definition of this volume you need to stop the jobs that are using it
-  depends_on = [data.nomad_plugin.smb]
-  plugin_id  = "smb"
-
-  volume_id = "unraid_media_photosvideos"
-  name      = "unraid_media_photosvideos"
-
-  external_id = "unraid_media_photosvideos"
-
-  capability {
-    access_mode     = "single-node-writer"
-    attachment_mode = "file-system"
+module "unraid_smb_immich_mediadump_photosvideos" {
+  source = "./modules/unraid_smb"
+  name   = "photosvideos"
+  id     = "unraid_mediadump_photosvideos"
+  share  = "media-dump"
+  subDir = "Photos and Videos"
 }
-
-  context = {
-    source = "//192.168.1.192/media"
-    subDir = "Photos and Videos" # Note: Needs to be manually created on the share
-  }
-
-  secrets = {
-    "username" = "nomad"
-    "password" = data.sops_file.secrets.data["unraid.nomad"]
-  }
-}
-
-resource "nomad_csi_volume_registration" "unraid_media_immich_encodedvideo" {
-  #Note: Before chaning the definition of this volume you need to stop the jobs that are using it
-  depends_on = [data.nomad_plugin.smb]
-  plugin_id  = "smb"
-
-  volume_id = "unraid_media_immich_encodedvideo"
-  name      = "unraid_media_immich_encodedvideo"
-
-  external_id = "unraid_media_immich_encodedvideo"
-
-  capability {
-    access_mode     = "single-node-writer"
-    attachment_mode = "file-system"
-  }
-
-  context = {
-    source = "//192.168.1.192/media"
-    subDir = "immich/encoded-video" # Note: Needs to be manually created on the share
-  }
-
-  secrets = {
-    "username" = "nomad"
-    "password" = data.sops_file.secrets.data["unraid.nomad"]
-  }
-}
-
-resource "nomad_csi_volume_registration" "unraid_mediadump_photosvideos" {
-  #Note: Before chaning the definition of this volume you need to stop the jobs that are using it
-  depends_on = [data.nomad_plugin.smb]
-  plugin_id  = "smb"
-
-  volume_id = "unraid_mediadump_photosvideos"
-  name      = "unraid_mediadump_photosvideos"
-
-  external_id = "unraid_mediadump_photosvideos"
-
-  capability {
-    access_mode     = "single-node-writer"
-    attachment_mode = "file-system"
-  }
-
-  context = {
-    source = "//192.168.1.192/media-dump"
-    subDir = "Photos and Videos" # Note: Needs to be manually created on the share
-  }
-
-  secrets = {
-    "username" = "nomad"
-    "password" = data.sops_file.secrets.data["unraid.nomad"]
-  }
-}
-

2-nomad-config/jellyfin.nomad.hcl

@@ -0,0 +1,88 @@
+job "jellyfin" {
+  group "jellyfin" {
+    count = 1
+
+    network {
+      port "http" {
+        to = 8096
+      }
+    }
+
+    task "jellyfin" {
+      driver = "docker"
+
+      config {
+        image = "lscr.io/linuxserver/jellyfin:latest"
+        ports = ["http"]
+      }
+
+      service {
+        name = "jellyfin"
+        port = "http"
+
+        tags = [
+          "traefik.enable=true",
+          "traefik.http.routers.jellyfin.middlewares=auth@file",
+          "traefik.http.routers.jellyfin-token.rule=Host(`c3ll7nbevl5j4j8rcnfxnr95q48fuayz-jellyfin.othrayte.one`)",
+        ]
+
+        check {
+          name     = "alive"
+          type     = "tcp"
+          port     = "http"
+          interval = "10s"
+          timeout  = "2s"
+        }
+      }
+
+      env {
+        PUID = 1000
+        PGID = 1000
+        TZ   = "Australia/Melbourne"
+
+        JELLYFIN_PublishedServerUrl = "https://jellyfin.othrayte.one"
+      }
+
+      volume_mount {
+        volume      = "unraid_appdata_jellyfin"
+        destination = "/config"
+        read_only   = false
+      }
+
+      volume_mount {
+        volume      = "unraid_media_jellyfin"
+        destination = "/data"
+        read_only   = false
+      }
+
+      resources {
+        cpu    = 500
+        memory = 2048
+      }
+    }
+
+    volume "unraid_appdata_jellyfin" {
+      type            = "csi"
+      read_only       = false
+      source          = "unraid_appdata_jellyfin"
+      access_mode     = "single-node-writer"
+      attachment_mode = "file-system"
+
+      mount_options {
+        mount_flags = ["uid=1000", "gid=1000"]
+      }
+    }
+
+    volume "unraid_media_jellyfin" {
+      type            = "csi"
+      read_only       = false
+      source          = "unraid_media_jellyfin"
+      access_mode     = "single-node-writer"
+      attachment_mode = "file-system"
+
+      mount_options {
+        mount_flags = ["nobrl", "uid=1000", "gid=1000"]
+      }
+    }
+  }
+}

2-nomad-config/jellyfin.tf

@@ -0,0 +1,15 @@
+
+resource "nomad_job" "jellyfin" {
+  jobspec = file("jellyfin.nomad.hcl")
+}
+
+module "appdata_jellyfin" {
+  source = "./modules/appdata"
+  name   = "jellyfin"
+}
+
+module "unraid_smb_jellyfin_media" {
+  source = "./modules/unraid_smb"
+  name   = "jellyfin"
+  share  = "media"
+}

2-nomad-config/modules/appdata/main.tf

@@ -0,0 +1,62 @@
+terraform {
+  required_providers {
+    sops = {
+      source  = "carlpett/sops"
+      version = "~> 0.5"
+    }
+  }
+}
+
+variable "name" {
+  description = "Name of the application, also used as subdir on the unraid appdata share"
+  type        = string
+}
+
+variable "id" {
+  description = "ID to use for the volume registration, defaults to name with - replaced by _"
+  type        = string
+  default     = null
+}
+
+variable "access_mode" {
+  description = "CSI volume access mode"
+  type        = string
+  default     = "single-node-writer"
+  validation {
+    condition     = contains(["single-node-writer", "multi-node-multi-writer"], var.access_mode)
+    error_message = "access_mode must be either 'single-node-writer' or 'multi-node-multi-writer'"
+  }
+}
+
+data "nomad_plugin" "smb" {
+  plugin_id        = "smb"
+  wait_for_healthy = true
+}
+
+data "sops_file" "secrets" {
+  source_file = "secrets/secrets.enc.json"
+}
+
+resource "nomad_csi_volume_registration" "this" {
+  depends_on = [data.nomad_plugin.smb]
+  plugin_id  = "smb"
+
+  volume_id   = var.id != null ? var.id : "unraid_appdata_${replace(var.name, "-", "_")}"
+  name        = var.id != null ? var.id : "unraid_appdata_${replace(var.name, "-", "_")}"
+  external_id = var.id != null ? var.id : "unraid_appdata_${replace(var.name, "-", "_")}"
+
+  capability {
+    access_mode     = var.access_mode
+    attachment_mode = "file-system"
+  }
+
+  context = {
+    source = "//betelgeuse-seven-unraid.lan/appdata"
+    subDir = var.name
+  }
+
+  secrets = {
+    "username" = "nomad"
+    "password" = data.sops_file.secrets.data["unraid.nomad"]
+  }
+}

2-nomad-config/modules/unraid_smb/main.tf

@@ -0,0 +1,62 @@
+terraform {
+  required_providers {
+    sops = {
+      source  = "carlpett/sops"
+      version = "~> 0.5"
+    }
+  }
+}
+
+variable "name" {
+  description = "Name of the volume registration"
+  type        = string
+}
+
+variable "id" {
+  description = "ID to use for the volume registration, defaults to name with - replaced by _"
+  type        = string
+  default     = null
+}
+
+variable "share" {
+  description = "Name of the SMB share on the unraid server"
+  type        = string
+}
+
+variable "subDir" {
+  description = "Subdirectory within the SMB share"
+  type        = string
+  default     = null
+}
+
+data "nomad_plugin" "smb" {
+  plugin_id        = "smb"
+  wait_for_healthy = true
+}
+
+data "sops_file" "secrets" {
+  source_file = "secrets/secrets.enc.json"
+}
+
+resource "nomad_csi_volume_registration" "this" {
+  depends_on = [data.nomad_plugin.smb]
+  plugin_id  = "smb"
+
+  volume_id   = var.id != null ? var.id : "unraid_${var.share}_${replace(var.name, "-", "_")}"
+  name        = var.id != null ? var.id : "unraid_${var.share}_${replace(var.name, "-", "_")}"
+  external_id = var.id != null ? var.id : "unraid_${var.share}_${replace(var.name, "-", "_")}"
+
+  capability {
+    access_mode     = "single-node-writer"
+    attachment_mode = "file-system"
+  }
+
+  context = merge({
+    source = "//betelgeuse-seven-unraid.lan/${var.share}"
+  }, var.subDir == null ? {} : { "subDir" = var.subDir })
+
+  secrets = {
+    "username" = "nomad"
+    "password" = data.sops_file.secrets.data["unraid.nomad"]
+  }
+}

2-nomad-config/prowlarr.nomad.hcl

@@ -0,0 +1,119 @@
+job "prowlarr" {
+  group "prowlarr" {
+    network {
+      mode = "bridge"
+      port "http" {
+        to = 9696
+      }
+    }
+
+    service {
+      connect {
+        sidecar_service {
+          proxy {
+            upstreams {
+              destination_name = "postgres"
+              local_bind_port  = 5432
+            }
+            upstreams {
+              destination_name = "sonarr-api"
+              local_bind_port  = 8989
+            }
+          }
+        }
+      }
+    }
+
+    service {
+      name = "prowlarr"
+      port = "http"
+
+      tags = [
+        "traefik.enable=true",
+        "traefik.http.routers.prowlarr.middlewares=auth@file",
+      ]
+
+      check {
+        type     = "http"
+        path     = "/"
+        interval = "10s"
+        timeout  = "2s"
+      }
+    }
+
+    service {
+      name         = "prowlarr-api"
+      port         = "http"
+      address_mode = "alloc" # Use allocation IP for Connect as the sidecar can't access the host's published port (hairpin/loopback NAT issue)
+
+      connect {
+        sidecar_service {}
+      }
+
+      check {
+        type     = "http"
+        path     = "/"
+        interval = "10s"
+        timeout  = "2s"
+      }
+    }
+
+    task "prowlarr" {
+      driver = "docker"
+
+      config {
+        image = "lscr.io/linuxserver/prowlarr:latest"
+        ports = ["http"]
+      }
+
+      env {
+        PUID = 1000
+        PGID = 1000
+        TZ   = "Australia/Melbourne"
+
+        # https://wiki.servarr.com/prowlarr/postgres-setup
+
+        # Disable internal auth to use Traefik + Authelia
+        PROWLARR__AUTH__REQUIRED = "Enabled"
+        PROWLARR__AUTH__METHOD   = "External"
+
+        PROWLARR__POSTGRES__USER   = "prowlarr"
+        PROWLARR__POSTGRES__HOST   = "localhost"
+        PROWLARR__POSTGRES__PORT   = "5432"
+        PROWLARR__POSTGRES__MAINDB = "prowlarr-main"
+        PROWLARR__POSTGRES__LOGDB  = "prowlarr-log"
+      }
+
+      volume_mount {
+        volume      = "unraid_appdata_prowlarr"
+        destination = "/config"
+        read_only   = false
+      }
+
+      resources {
+        cpu    = 150
+        memory = 512
+      }
+
+      template {
+        data        = <<EOH
+PROWLARR__POSTGRES__PASSWORD="{{ with nomadVar "nomad/jobs/prowlarr" }}{{ .database_pw }}{{ end }}"
+EOH
+        destination = "secrets/db.env"
+        env         = true # Load the file as environment variables
+      }
+    }
+
+    volume "unraid_appdata_prowlarr" {
+      type            = "csi"
+      read_only       = false
+      source          = "unraid_appdata_prowlarr"
+      access_mode     = "single-node-writer"
+      attachment_mode = "file-system"
+
+      mount_options {
+        mount_flags = ["uid=1000", "gid=1000"]
+      }
+    }
+  }
+}

2-nomad-config/prowlarr.tf

@@ -0,0 +1,32 @@
+resource "nomad_job" "prowlarr" {
+  jobspec = file("prowlarr.nomad.hcl")
+}
+
+resource "nomad_variable" "prowlarr" {
+  path = "nomad/jobs/prowlarr"
+  items = {
+    database_pw = data.sops_file.secrets.data["prowlarr.database_pw"]
+  }
+}
+
+# https://wiki.servarr.com/prowlarr/postgres-setup
+resource "postgresql_role" "prowlarr" {
+  name     = "prowlarr"
+  password = data.sops_file.secrets.data["prowlarr.database_pw"]
+  login    = true
+}
+
+resource "postgresql_database" "prowlarr_main" {
+  name  = "prowlarr-main"
+  owner = postgresql_role.prowlarr.name
+}
+
+resource "postgresql_database" "prowlarr_log" {
+  name  = "prowlarr-log"
+  owner = postgresql_role.prowlarr.name
+}
+
+module "appdata_prowlarr" {
+  source = "./modules/appdata"
+  name   = "prowlarr"
+}

2-nomad-config/readme.md

@@ -1,7 +1,7 @@
 # Terraform State
 
 Mount the state on the fileshare to 2-nomad-config/.tfstate/
-`sudo mount -t cifs //192.168.1.192/appdata/terraform /home/othrayte/Code/infra/2-nomad-config/.tfstate/ -o rw,username=othrayte,password=<pw>,uid=$(id -u),gid=$(id -g)`
+`sudo mount -t cifs //betelgeuse-seven-unraid.lan/appdata/terraform /home/othrayte/Code/infra/2-nomad-config/.tfstate/ -o rw,username=othrayte,password=<pw>,uid=$(id -u),gid=$(id -g)`
 
 # Tailscale Oauth Client
 
@@ -20,6 +20,7 @@ Edit the secrets using `sops secrets/secrets.enc.json`
 # Bootstrapping (starting without PostgreSQL running)
 
 terraform apply -target=module.data
+terraform apply -target=module.ingress
 
 ## Restoring PostgreSQL DBs
 

2-nomad-config/secrets/secrets.enc.json

@@ -33,6 +33,16 @@
 	"immich": {
 		"database_pw": "ENC[AES256_GCM,data:SUyMGqu7deZyZpVt,iv:asZehOvn/JamwFyS+Xl9Xpr4JFkKlJjHVw7LywYOxTc=,tag:plRvuv7+ievfEhxurBl7YQ==,type:str]"
 	},
+	"sonarr": {
+		"database_pw": "ENC[AES256_GCM,data:TN381ZYJLeUHX9U3Jnd9+w==,iv:lKaMYHeaSGXJd0/EGxkDY2l2v62xG3xs8TVC0HwXL94=,tag:3z5rK+2RfJHJdQc7KC9KmA==,type:str]"
+	},
+	"pia": {
+		"user": "ENC[AES256_GCM,data:kniAs2gCTq4=,iv:1Oaht02fFSQwzWmWEtjsJZCJChPJsZhwRyux8dMY2CU=,tag:NqWaUhuYTSFZZK/CpSisdg==,type:str]",
+		"pass": "ENC[AES256_GCM,data:c8qWGcaI0p7MyQ==,iv:/3ehYrgdDwjzFdXyX/vKTK+zt6u7gWNRZBIdWDG1KiE=,tag:jqfIMnB1OKchBZ4U2s1o4g==,type:str]"
+	},
+	"prowlarr": {
+		"database_pw": "ENC[AES256_GCM,data:FkW5LPoyn8bh0UfWcFq3og==,iv:SFq4Xsdz3FfCDyPjIaAmz5nsC/SPdFrR03GCr3KE/nw=,tag:PVYj7hSWDnfeE7igSXGBSA==,type:str]"
+	},
 	"sops": {
 		"age": [
 			{
@@ -40,8 +50,8 @@
 				"enc": "-----BEGIN AGE ENCRYPTED FILE-----\nYWdlLWVuY3J5cHRpb24ub3JnL3YxCi0+IFgyNTUxOSByUWM4ZDVVbGFrUGdMRHBX\nUFBmU3Nlc0RBSzhFK0tHNHpkQXUvUVdiZUZJCmpRN1lFdENpWW0rcThjVlVQNUl6\nWnlLU0RnQ3FZby81Ly8xTFBrek9nMncKLS0tIFQ4UTRNOC9CRmx4OFJWem1wckZz\nUDFTSzdWZldFK3FqcTNWTWRyNDhHQ2MKS811mR5xn7qiC/aVgPFYJ5c6Q3zxRfcr\nHcvxUvB01vNJKZpRg92vvKPkV6lQO3DXCT98OdfwiymlEOvYxg71Pg==\n-----END AGE ENCRYPTED FILE-----\n"
 			}
 		],
-		"lastmodified": "2025-10-13T12:19:46Z",
-		"mac": "ENC[AES256_GCM,data:QJ1Prqf37xMZbvyMvjBVxZOiOr07CmCYrWmr+5hwDsEmG4eEC9sPF/UY+/Cy2OTzsMp+cHb6C3maAo09O171wj6nJIZucg3B9fjEW2+4AoO217G4vmauMl3FFkut2CuvVV9zt2B/fLAskRg/yeYYOhjzPkWA6lyeV31sV5ZQ6Kw=,iv:5WfkmNr5vdfTqp6+INjQN/Zmc7/iJNc/2auO9h3En08=,tag:snBgJyMzBXVAkV3zERkK8g==,type:str]",
+		"lastmodified": "2025-11-18T12:09:57Z",
+		"mac": "ENC[AES256_GCM,data:zchzaSPjJVbUBzXTrRPGAtQE6xzqxMjTCXRABvwEvgNqLO7i2C/d04hI+pwOuLWyZXiUfqHlGt798ZnP5+MJi249FJmK08l8dAXxKSc+KSc4EfDoF+jWiwmoDEf5SypyHL9RPTeI7zoSJ0IxhtP3zZcD/7Q2PPG7cLDBKHdTJFU=,iv:+UiyEfMtAObZ/vvs2ZaIup9OxxP0uqSmo+h45PrymLk=,tag:f/D8417EGjuOfSdzZtir4Q==,type:str]",
 		"encrypted_regex": "^(.*)$",
 		"version": "3.10.2"
 	}

2-nomad-config/sonarr.nomad.hcl

@@ -0,0 +1,140 @@
+job "sonarr" {
+  group "sonarr" {
+    network {
+      mode = "bridge"
+      port "http" {
+        to = 8989
+      }
+    }
+    service {
+      connect {
+        sidecar_service {
+          proxy {
+            upstreams {
+              destination_name = "postgres"
+              local_bind_port  = 5432
+            }
+            upstreams {
+              destination_name = "deluge-api"
+              local_bind_port  = 8112
+            }
+            upstreams {
+              destination_name = "prowlarr-api"
+              local_bind_port  = 9696
+            }
+          }
+        }
+      }
+    }
+
+    service {
+      name = "sonarr"
+      port = "http"
+
+      tags = [
+        "traefik.enable=true",
+        "traefik.http.routers.sonarr.middlewares=auth@file",
+      ]
+
+      check {
+        type     = "http"
+        path     = "/"
+        interval = "10s"
+        timeout  = "2s"
+      }
+    }
+
+    service {
+      name         = "sonarr-api"
+      port         = "http"
+      address_mode = "alloc" # Use allocation IP for Connect as the sidecar can't access the host's published port (hairpin/loopback NAT issue)
+
+      connect {
+        sidecar_service {}
+      }
+
+      check {
+        type     = "http"
+        path     = "/"
+        interval = "10s"
+        timeout  = "2s"
+      }
+    }
+
+    task "sonarr" {
+      driver = "docker"
+
+      config {
+        image = "lscr.io/linuxserver/sonarr:latest"
+        ports = ["http"]
+      }
+
+      env {
+        PUID = 1000
+        PGID = 1000
+        TZ   = "Australia/Melbourne"
+
+        # https://wiki.servarr.com/sonarr/environment-variables
+
+        # Disable internal auth to use Traefik + Authelia
+        SONARR__AUTH__REQUIRED = "Enabled"
+        SONARR__AUTH__METHOD   = "External"
+
+        SONARR__POSTGRES__USER   = "sonarr"
+        SONARR__POSTGRES__HOST   = "localhost"
+        SONARR__POSTGRES__PORT   = "5432"
+        SONARR__POSTGRES__MAINDB = "sonarr-main"
+        SONARR__POSTGRES__LOGDB  = "sonarr-log"
+      }
+
+      volume_mount {
+        volume      = "unraid_appdata_sonarr"
+        destination = "/config"
+        read_only   = false
+      }
+
+      volume_mount {
+        volume      = "unraid_media_sonarr"
+        destination = "/data"
+        read_only   = false
+      }
+
+      resources {
+        cpu    = 150
+        memory = 1024
+      }
+
+      template {
+        data        = <<EOH
+SONARR__POSTGRES__PASSWORD="{{ with nomadVar "nomad/jobs/sonarr" }}{{ .database_pw }}{{ end }}"
+EOH
+        destination = "secrets/db.env"
+        env         = true # Load the file as environment variables
+      }
+    }
+
+    volume "unraid_appdata_sonarr" {
+      type            = "csi"
+      read_only       = false
+      source          = "unraid_appdata_sonarr"
+      access_mode     = "single-node-writer"
+      attachment_mode = "file-system"
+
+      mount_options {
+        mount_flags = ["uid=1000", "gid=1000"]
+      }
+    }
+
+    volume "unraid_media_sonarr" {
+      type            = "csi"
+      read_only       = false
+      source          = "unraid_media_sonarr"
+      access_mode     = "single-node-writer"
+      attachment_mode = "file-system"
+
+      mount_options {
+        mount_flags = ["nobrl", "uid=1000", "gid=1000"]
+      }
+    }
+  }
+}

2-nomad-config/sonarr.tf

@@ -0,0 +1,38 @@
+resource "nomad_job" "sonarr" {
+  jobspec = file("sonarr.nomad.hcl")
+}
+
+resource "nomad_variable" "sonarr" {
+  path = "nomad/jobs/sonarr"
+  items = {
+    database_pw = data.sops_file.secrets.data["sonarr.database_pw"]
+  }
+}
+
+# https://wiki.servarr.com/sonarr/postgres-setup#schema-creation
+resource "postgresql_role" "sonarr" {
+  name     = "sonarr"
+  password = data.sops_file.secrets.data["sonarr.database_pw"]
+  login    = true
+}
+
+resource "postgresql_database" "sonarr_main" {
+  name  = "sonarr-main"
+  owner = postgresql_role.sonarr.name
+}
+
+resource "postgresql_database" "sonarr_log" {
+  name  = "sonarr-log"
+  owner = postgresql_role.sonarr.name
+}
+
+module "appdata_sonarr" {
+  source = "./modules/appdata"
+  name   = "sonarr"
+}
+
+module "unraid_smb_sonarr_media" {
+  source = "./modules/unraid_smb"
+  name   = "sonarr"
+  share  = "media"
+}

2-nomad-config/teamsstatus.nomad.hcl

@@ -1,345 +0,0 @@
-job "teamsstatus" {
-  group "app" {
-    task "teamsstatus" {
-      driver = "docker"
-
-      config {
-        image   = "python:3.11-slim"
-        command = "/local/start.sh"
-      }
-
-      # Template for the startup script
-      template {
-        data        = <<EOF
-#!/bin/bash
-set -e
-
-cd /local
-
-echo "Starting Teams Status Updater service..."
-echo "Installing required Python packages..."
-pip install msal requests
-
-echo "Running Teams Status Updater script..."
-exec python teamsstatus_standalone.py 2>&1
-EOF
-        destination = "local/start.sh"
-        perms       = "755"
-      }
-
-      # Template for the token cache
-      template {
-        data        = "{{ with nomadVar \"nomad/jobs/teamsstatus\" }}{{ .token_cache_json }}{{ end }}"
-        destination = "local/token_cache.json"
-      }
-
-      # Template for the Python script
-      template {
-        data        = <<EOF
-import logging
-import time
-from datetime import datetime, timedelta, timezone
-import random
-import json
-import msal
-import requests
-import os
-import atexit
-
-# Configure logging
-logging.basicConfig(level=logging.INFO)
-
-# Embedded journey data
-JOURNEY_DATA = '''Day	Start Time AEST	End Time AEST	Start Dist	End Dist	Start Location	End Location
-08/06/2025	08:00:00	19:10:00	0km	973km	Melbourne	Port Pirie SA
-09/06/2025	07:30:00	19:35:00	973km	2119km	Port Pirie SA	Mundrabilla WA
-10/06/2025	06:45:00	15:38:00	2119km	2916km	Mundrabilla WA	Kalgoorlie WA
-11/06/2025	10:45:00	17:55:00	2916km	3512km	Kalgoorlie WA	Perth
-13/06/2025	07:00:00	13:58:00	3512km	4083km	Perth	Kalbarri WA
-15/06/2025	07:00:00	16:52:00	4083km	4862km	Kalbarri WA	Coral Bay WA
-18/06/2025	06:00:00	16:52:00	4862km	5554km	Coral Bay WA	Karijini NP WA
-21/06/2025	14:00:00	15:21:00	5554km	5686km	Karijini NP WA	Karijini NP WA
-22/06/2025	06:00:00	16:23:00	5686km	6559km	Karijini NP WA	Broome WA
-23/06/2025	06:00:00	19:10:00	6559km	7688km	Broome WA	Kununurra WA
-27/06/2025	06:00:00	16:29:00	7688km	8593km	Kununurra WA	Derby WA
-28/06/2025	07:00:00	16:06:00	8593km	9358km	Derby WA	Port Hedland WA
-29/06/2025	07:00:00	16:31:00	9358km	10150km	Port Hedland WA	Exmouth WA
-02/07/2025	07:00:00	15:13:00	10150km	10866km	Exmouth WA	Shark Bay WA
-05/07/2025	07:00:00	17:12:00	10866km	11712km	Shark Bay WA	Fremantle WA
-06/07/2025	07:00:00	15:27:00	11712km	12411km	Fremantle WA	Esperance WA
-08/07/2025	06:00:00	18:09:00	12411km	13144km	Esperance WA	Madura WA
-09/07/2025	06:45:00	16:39:00	13144km	13821km	Madura WA	Ceduna SA
-11/07/2025	08:30:00	17:46:00	13821km	14599km	Ceduna SA	Adelaide
-12/07/2025	08:30:00	18:52:00	14599km	15348km	Adelaide	Melbourne'''
-
-# Global variables for journey segments
-_segments = []
-
-def setup_token_cache(cache_filename="token_cache.json"):
-    """Set up and return a serializable token cache"""
-    cache = msal.SerializableTokenCache()
-    
-    cache.deserialize(open(cache_filename, "r").read())
-    
-    atexit.register(
-        lambda: open(cache_filename, "w").write(cache.serialize())
-        if cache.has_state_changed else None
-    )
-    return cache
-
-def get_msal_app(client_id, authority="https://login.microsoftonline.com/organizations", cache_filename="token_cache.json"):
-    """Create and return an MSAL PublicClientApplication"""
-    cache = setup_token_cache(cache_filename)
-    return msal.PublicClientApplication(
-        client_id,
-        authority=authority,
-        token_cache=cache,
-    )
-
-def acquire_token(app, scope):
-    """Acquire a token using the MSAL app"""
-    result = None
-    
-    # Check if user account exists in cache
-    accounts = app.get_accounts(username=None)
-    if accounts:
-        logging.debug("Account(s) exists in cache, probably with token too. Let's try.")
-        logging.debug("Account(s) already signed in:")
-        for a in accounts:
-            logging.debug(a["username"])
-        chosen = accounts[0]  # Assuming the end user chose this one to proceed
-        logging.debug(f"Automatically using first account: {chosen['username']}")
-        # Try to find a token in cache for this account
-        result = app.acquire_token_silent(scope, account=chosen)
-    
-    # If no suitable token was found, get a new one
-    if not result:
-        logging.debug("No suitable token exists in cache. Let's get a new one from AAD.")
-        print("A local browser window will be open for you to sign in. CTRL+C to cancel.")
-        result = app.acquire_token_interactive(scope)
-    
-    # Validate the result
-    if "access_token" not in result:
-        logging.error(result.get("error"))
-        logging.error(result.get("error_description"))
-        logging.debug(f"Correlation ID: {result.get('correlation_id')}")
-        return None
-        
-    return result["access_token"]
-
-def set_teams_status_message(access_token, user_id, status_message, expiration_date_time="2025-06-01T12:00:00", time_zone="UTC"):
-    """Set the status message for a Teams user"""
-    url = f"https://graph.microsoft.com/v1.0/users/{user_id}/presence/microsoft.graph.setStatusMessage"
-    
-    payload = {
-        "statusMessage": {
-            "message": {
-                "content": status_message + "<pinnednote></pinnednote>",
-                "contentType": "text",
-            }
-        },
-        "expirationDateTime": {
-            "dateTime": expiration_date_time,
-            "timeZone": time_zone
-        },
-    }
-    
-    headers = {
-        'Authorization': f'Bearer {access_token}',
-        'Content-Type': 'application/json'
-    }
-    
-    logging.debug(f"Setting status message for user {user_id}")
-    
-    response = requests.post(url, json=payload, headers=headers)
-    
-    if response.status_code == 200:
-        logging.info(f"Teams status message set to: {status_message}")
-        return True
-    else:
-        logging.error(f"Failed to set Teams status message: {response.status_code}")
-        return False
-
-def _load_segments():
-    """Load the journey segments from embedded data into memory"""
-    global _segments
-    if _segments:  # Already loaded
-        return
-        
-    aest = timezone(timedelta(hours=10))
-    
-    for line in JOURNEY_DATA.split('\n')[1:]:  # Skip header
-        day, start_time, end_time, start_dist, end_dist, start_loc, end_loc = line.strip().split('\t')
-            
-        # Convert day and times to datetime in AEST
-        day_start = datetime.strptime(f"{day} {start_time}", "%d/%m/%Y %H:%M:%S").replace(tzinfo=aest)
-        day_end = datetime.strptime(f"{day} {end_time}", "%d/%m/%Y %H:%M:%S").replace(tzinfo=aest)
-        
-        # Extract the numeric distance values
-        start_dist = int(start_dist.rstrip('km'))
-        end_dist = int(end_dist.rstrip('km'))
-        
-        _segments.append({
-            'start_time': day_start,
-            'end_time': day_end,
-            'start_dist': start_dist,
-            'end_dist': end_dist,
-            'start_location': start_loc,
-            'end_location': end_loc
-        })
-
-def get_trip_info(target_datetime):
-    """Determine the distance travelled and locations for the current datetime."""
-    if target_datetime.tzinfo is None:
-        raise ValueError("target_datetime must be timezone-aware")
-    
-    # Ensure data is loaded
-    _load_segments()
-    
-    # Before journey starts
-    if not _segments or target_datetime < _segments[0]['start_time']:
-        start_loc = end_loc = _segments[0]['start_location']
-        return (0, start_loc, end_loc)
-    
-    # During journey
-    for i, segment in enumerate(_segments):
-        # If target is before this segment starts
-        if target_datetime < segment['start_time']:
-            prev_segment = _segments[i-1]
-            return (prev_segment['end_dist'], prev_segment['end_location'], prev_segment['end_location'])
-            
-        # If target is during this segment, interpolate
-        if segment['start_time'] <= target_datetime <= segment['end_time']:
-            # Calculate what fraction of the segment has elapsed
-            total_seconds = (segment['end_time'] - segment['start_time']).total_seconds()
-            elapsed_seconds = (target_datetime - segment['start_time']).total_seconds()
-            fraction = elapsed_seconds / total_seconds
-            
-            # Interpolate the distance
-            distance_delta = segment['end_dist'] - segment['start_dist']
-            current_dist = segment['start_dist'] + int(distance_delta * fraction)
-            return (current_dist, segment['start_location'], segment['end_location'])
-        
-        # Between segments
-        if i < len(_segments) - 1:
-            next_segment = _segments[i + 1]
-            if segment['end_time'] < target_datetime < next_segment['start_time']:
-                return (segment['end_dist'], segment['end_location'], segment['end_location'])
-    
-    # After journey ends
-    return (_segments[-1]['end_dist'], _segments[-1]['end_location'], _segments[-1]['end_location'])
-
-def build_message(distance, start_loc, end_loc):
-    """Build the status message based on distance and locations"""
-    message = "On leave"
-    if distance > 13144:
-        message += f", driving my EV back from WA"
-    elif distance > 2118:
-        message += f", driving my EV around WA"
-    elif distance > 0:
-        message += f", driving my EV to WA"
-    
-    if distance > 0:
-        distance += random.randint(-5, 5)
-        message += f", {distance}kms travelled so far"
-        if start_loc != end_loc:
-            message += f", next stop {end_loc}"
-        else:
-            message += f", near {start_loc}"
-            
-    message += ", returning July 21st. Contacts {CIM: Grant Gorfine, Inserts: Daniel Pate, DevOps: Rob Duncan, else: Andrian Zubovic}"
-    return message
-
-def main():
-    test_mode = False # Set to True to run in test mode
-    time_scale = 1 # 1/600  # Set to 1/60 to run at 1 second per minute, 1 for normal speed
-    
-    # Set start time to 7:30 AM AEST (UTC+10) on June 8th, 2025
-    aest = timezone(timedelta(hours=10))
-    start_time = datetime.now(aest)
-    date_offset = datetime(2025, 6, 8, 7, 30, 0, tzinfo=aest) - start_time
-
-    if test_mode:
-        logging.info("Running in test mode - status messages will not actually be set")
-    
-    app = get_msal_app(client_id = "e6cda941-949f-495e-88f5-10eb45ffa0e7")
-    
-    last_token_refresh = 0
-    # Token refresh interval (60 minutes in seconds)
-    TOKEN_REFRESH_INTERVAL = int(60 * 60)  # Scale the 1 hour refresh interval
-    
-    old_distance = -1
-    while True:
-        try:
-            # Check if we need to refresh the token
-            current_time = time.time()
-            if current_time - last_token_refresh >= TOKEN_REFRESH_INTERVAL or last_token_refresh == 0:
-                logging.info("Acquiring/refreshing access token...")
-                access_token = acquire_token(app, scope = ["https://graph.microsoft.com/Presence.ReadWrite"])
-                if not access_token:
-                    logging.error("Failed to acquire token")
-                    exit(1)
-                last_token_refresh = current_time
-                logging.info("Token successfully refreshed")
-            
-            # Set the status message
-            now = datetime.now(aest)  # Get current time in AEST
-            if time_scale != 1:
-                # Adjust the current time based on the time scale
-                now = start_time + (now - start_time) / time_scale
-                now += date_offset  # Adjust to the target start time
-            distance, start_loc, end_loc = get_trip_info(now)  # We only need distance for comparison
-            if distance != old_distance:
-                message = build_message(distance, start_loc, end_loc)
-                timestamp = now.strftime("%Y-%m-%d %H:%M:%S %Z")
-                if not test_mode:
-                    logging.info(f"[{timestamp}] Message: {message}")
-                    success = set_teams_status_message(
-                        access_token = access_token, 
-                        user_id = "1b625872-d8a8-42f4-b237-dfa6d8062360",
-                        status_message = message,
-                    )
-                else:
-                    logging.info(f"[TEST MODE] [{timestamp}] Message: {message}")
-                    success = True
-            else:
-                logging.debug("Status message has not changed, skipping update")
-                success = True
-            old_distance = distance
-
-            if success:
-                wait_time = 900 * time_scale  # Scale the 15 minute wait time
-                logging.debug(f"Waiting {wait_time} seconds before updating status message again...")
-                time.sleep(wait_time)
-            else:
-                last_token_refresh = 0  # Reset token refresh time on failure
-        except KeyboardInterrupt:
-            logging.info("Status update interrupted by user. Exiting...")
-            break
-        except Exception as e:
-            logging.error(f"An error occurred: {e}")
-            time.sleep(300)  # Wait 5 minutes before retrying
-        
-    return 0
-
-if __name__ == "__main__":
-    exit(main())
-
-EOF
-        destination = "local/teamsstatus_standalone.py"
-      }
-
-      resources {
-        cpu    = 500
-        memory = 256
-      }
-    }
-
-    restart {
-      attempts = 3
-      interval = "5m"
-      delay    = "15s"
-      mode     = "fail"
-    }
-  }
-}

2-nomad-config/teamsstatus.tf

@@ -1,12 +0,0 @@
-# Disabled
-
-# resource "nomad_job" "teamsstatus" {
-#   jobspec = file("${path.module}/teamsstatus.nomad.hcl")
-# }
-
-# resource "nomad_variable" "teamsstatus" {
-#   path = "nomad/jobs/teamsstatus"
-#   items = {
-#     token_cache_json = file("${path.module}/token_cache.json")
-#   }
-# }

2-nomad-config/transfer.tf

@@ -2,53 +2,14 @@ resource "nomad_job" "transfer" {
   jobspec = file("transfer.nomad.hcl")
 }
 
-resource "nomad_csi_volume_registration" "unraid_transfer" {
-  #Note: Before chaning the definition of this volume you need to stop the jobs that are using it
-  depends_on = [data.nomad_plugin.smb]
-  plugin_id  = "smb"
-
-  volume_id = "unraid_transfer"
-  name      = "unraid_transfer"
-
-  external_id = "unraid_transfer"
-
-  capability {
-    access_mode     = "single-node-writer"
-    attachment_mode = "file-system"
+module "unraid_smb_transfer" {
+  source = "./modules/unraid_smb"
+  name   = "transfer"
+  id     = "unraid_transfer"
+  share  = "transfer"
 }
 
-  context = {
-    source = "//192.168.1.192/transfer"
-  }
-
-  secrets = {
-    "username" = "anon"
-    "password" = ""
-  }
-}
-
-resource "nomad_csi_volume_registration" "unraid_appdata_transferfilebrowser" {
-  #Note: Before chaning the definition of this volume you need to stop the jobs that are using it
-  depends_on = [data.nomad_plugin.smb]
-  plugin_id  = "smb"
-
-  volume_id = "unraid_appdata_transferfilebrowser"
-  name      = "unraid_appdata_transferfilebrowser"
-
-  external_id = "unraid_appdata_transferfilebrowser"
-
-  capability {
-    access_mode     = "single-node-writer"
-    attachment_mode = "file-system"
-  }
-
-  context = {
-    source = "//192.168.1.192/appdata"
-    subDir = "transferfilebrowser" # Note: Needs to be manually created on the share
-  }
-
-  secrets = {
-    "username" = "nomad"
-    "password" = data.sops_file.secrets.data["unraid.nomad"]
-  }
+module "appdata_transferfilebrowser" {
+  source = "./modules/appdata"
+  name   = "transferfilebrowser"
 }

2-nomad-config/unifi.nomad.hcl

@@ -0,0 +1,50 @@
+job "unifi-network" {
+  group "unifi-network" {
+    count = 1
+
+    task "unifi-controller" {
+      driver = "docker"
+
+      config {
+        image = "jacobalberty/unifi:v9.5.21"
+
+        // Fixed IP on the actual network so that devices can find it
+        network_mode = "macvlan"
+        ipv4_address = "192.168.1.50"
+      }
+
+      env {
+        TZ                 = "Australia/Melbourne"
+        SYSTEM_IP          = "192.168.1.50"
+        JVM_INIT_HEAP_SIZE = "1024M"
+        JVM_MAX_HEAP_SIZE  = "1024M"
+        UNIFI_STDOUT       = "true"
+      }
+
+      volume_mount {
+        volume      = "unraid_appdata_unifi_network"
+        destination = "/unifi" # Expected root directory (contains data, log, cert subdirs)
+        read_only   = false
+      }
+
+      resources {
+        cpu        = 200
+        memory     = 1850
+        memory_max = 2500
+      }
+    }
+
+    # CSI volume for UniFi Controller persistent data/logs
+    volume "unraid_appdata_unifi_network" {
+      type            = "csi"
+      read_only       = false
+      source          = "unraid_appdata_unifi_network"
+      access_mode     = "single-node-writer"
+      attachment_mode = "file-system"
+
+      mount_options {
+        mount_flags = ["uid=0", "gid=0"]
+      }
+    }
+  }
+}

2-nomad-config/unifi.tf

@@ -0,0 +1,9 @@
+
+resource "nomad_job" "unifi_network" {
+  jobspec = file("unifi.nomad.hcl")
+}
+
+module "appdata_unifi_network" {
+  source = "./modules/appdata"
+  name   = "unifi-network"
+}