resource "nomad_job" "prowlarr" {
  jobspec = file("prowlarr.nomad.hcl")
}

resource "nomad_variable" "prowlarr" {
  path = "nomad/jobs/prowlarr"
  items = {
    database_pw = data.sops_file.secrets.data["prowlarr.database_pw"]
  }
}

# https://wiki.servarr.com/prowlarr/postgres-setup
resource "postgresql_role" "prowlarr" {
  name     = "prowlarr"
  password = data.sops_file.secrets.data["prowlarr.database_pw"]
  login    = true
}

resource "postgresql_database" "prowlarr_main" {
  name  = "prowlarr-main"
  owner = postgresql_role.prowlarr.name
}

resource "postgresql_database" "prowlarr_log" {
  name  = "prowlarr-log"
  owner = postgresql_role.prowlarr.name
}

resource "nomad_csi_volume_registration" "unraid_appdata_prowlarr" {
  #Note: Before chaning the definition of this volume you need to stop the jobs that are using it
  depends_on = [data.nomad_plugin.smb]
  plugin_id  = "smb"

  volume_id = "unraid_appdata_prowlarr"
  name      = "unraid_appdata_prowlarr"

  external_id = "unraid_appdata_prowlarr"

  capability {
    access_mode     = "single-node-writer"
    attachment_mode = "file-system"
  }

  context = {
    source = "//betelgeuse-seven-unraid.lan/appdata"
    subDir = "prowlarr" # Note: Needs to be manually created on the share
  }

  secrets = {
    "username" = "nomad"
    "password" = data.sops_file.secrets.data["unraid.nomad"]
  }
}