resource "nomad_job" "sonarr" {
  jobspec = file("sonarr.nomad.hcl")
}

resource "nomad_variable" "sonarr" {
  path = "nomad/jobs/sonarr"
  items = {
    database_pw = data.sops_file.secrets.data["sonarr.database_pw"]
  }
}

# https://wiki.servarr.com/sonarr/postgres-setup#schema-creation
resource "postgresql_role" "sonarr" {
  name     = "sonarr"
  password = data.sops_file.secrets.data["sonarr.database_pw"]
  login    = true
}

resource "postgresql_database" "sonarr_main" {
  name  = "sonarr-main"
  owner = postgresql_role.sonarr.name
}

resource "postgresql_database" "sonarr_log" {
  name  = "sonarr-log"
  owner = postgresql_role.sonarr.name
}

resource "nomad_csi_volume_registration" "unraid_appdata_sonarr" {
  #Note: Before chaning the definition of this volume you need to stop the jobs that are using it
  depends_on = [data.nomad_plugin.smb]
  plugin_id  = "smb"

  volume_id = "unraid_appdata_sonarr"
  name      = "unraid_appdata_sonarr"

  external_id = "unraid_appdata_sonarr"

  capability {
    access_mode     = "single-node-writer"
    attachment_mode = "file-system"
  }

  context = {
    source = "//betelgeuse-seven-unraid.lan/appdata"
    subDir = "sonarr" # Note: Needs to be manually created on the share
  }

  secrets = {
    "username" = "nomad"
    "password" = data.sops_file.secrets.data["unraid.nomad"]
  }
}

resource "nomad_csi_volume_registration" "unraid_media_sonarr" {
  #Note: Before chaning the definition of this volume you need to stop the jobs that are using it
  depends_on = [data.nomad_plugin.smb]
  plugin_id  = "smb"

  volume_id = "unraid_media_sonarr"
  name      = "unraid_media_sonarr"

  external_id = "unraid_media_sonarr"

  capability {
    access_mode     = "single-node-writer"
    attachment_mode = "file-system"
  }

  context = {
    source = "//betelgeuse-seven-unraid.lan/media"
  }

  secrets = {
    "username" = "nomad"
    "password" = data.sops_file.secrets.data["unraid.nomad"]
  }
}